我有一个关于反序列化的问题。我可以设想一个使用 Data.Data、Data.Typeable 或 GHC.Generics 的解决方案，但我很好奇它是否可以在没有泛型、SYB 或元编程的情况下完成。

问题描述:

给定已知包含本地定义代数数据类型字段的 [String] 列表，我想反序列化 [String] 以构造目标数据类型。我可以编写一个解析器来执行此操作，但我正在寻找一种通用解决方案，该解决方案将反序列化为程序中定义的任意数量的数据类型，而无需为每种类型编写解析器。了解代数类型所具有的值构造函数的数量和类型后，就可以简单地对每个字符串执行读取 以生成构建该类型所需的适当值。但是，我不想使用泛型、反射、SYB 或元编程(除非不可能)。

假设我定义了大约 50 种与此类似的类型(所有简单的代数类型都由基本基元组成(没有嵌套或递归类型，只有基元的不同组合和顺序):

data NetworkMsg = NetworkMsg { field1 :: Int, field2 :: Int, field3 :: Double} 
 
data NetworkMsg2 = NetworkMsg2 { field1 :: Double, field2 :: Int, field3 :: Double } 

我可以使用在每个 [String] 之前解析的标记 ID 来确定与我通过网络接收到的 [String] 关联的数据类型。

可能的推测解路径:

由于数据构造函数在 Haskell 中是一等值，并且实际上有一个类型——NetworkMsg 构造函数是否可以被认为是一个函数，例如:

NetworkMsg :: Int -> Int -> Double -> NetworkMsg 

我能否使用 uncurryN 将此函数转换为元组函数，然后将 [String] 复制到函数现在采用的相同形状的元组中？

NetworkMsg' :: (Int, Int, Double) -> NetworkMsg 

我认为这行不通，因为我需要了解值构造函数和类型信息，这需要 Data.Typeable、反射或其他一些元编程技术。

基本上，我正在寻找许多类型的自动反序列化，而无需编写类型实例声明或在运行时分析类型的形状。如果它不可行，我将采用其他方式。

请您参考如下方法:

你是对的，因为构造函数本质上只是函数，所以你可以通过为函数编写实例来为任意数量的类型编写通用实例。您仍然需要编写一个单独的实例 不过，对于所有不同数量的参数。

{-# LANGUAGE FlexibleInstances #-} 
{-# LANGUAGE MultiParamTypeClasses #-} 
 
import Text.Read 
import Control.Applicative 
 
class FieldParser p r where 
    parseFields :: p -> [String] -> Maybe r 
 
instance Read a => FieldParser (a -> r) r where 
    parseFields con [a] = con <$> readMaybe a 
    parseFields _ _ = Nothing 
 
instance (Read a, Read b) => FieldParser (a -> b -> r) r where 
    parseFields con [a, b] = con <$> readMaybe a <*> readMaybe b 
    parseFields _ _ = Nothing 
 
instance (Read a, Read b, Read c) => FieldParser (a -> b -> c -> r) r where 
    parseFields con [a, b, c] = con <$> readMaybe a <*> readMaybe b <*> readMaybe c 
    parseFields _ _ = Nothing 
 
{- etc. for as many arguments as you need -} 

现在你可以使用这个类型类来解析基于构造函数的任何消息，只要类型检查器能够从上下文中找出结果消息类型(即它不能简单地从给定的构造函数中推断出来)对于这些类型的多参数类型类实例)。

data Test1 = Test1 {fieldA :: Int} deriving Show 
data Test2 = Test2 {fieldB ::Int, fieldC :: Float} deriving Show 
 
test :: String -> [String] -> IO () 
test tag fields = case tag of 
    "Test1" -> case parseFields Test1 fields of 
        Just (a :: Test1) -> putStrLn $ "Succesfully parsed " ++ show a 
        Nothing -> putStrLn "Parse error" 
    "Test2" -> case parseFields Test2 fields of 
        Just (a :: Test2) -> putStrLn $ "Succesfully parsed " ++ show a 
        Nothing -> putStrLn "Parse error" 

不过，我想知道您在应用程序中究竟是如何使用消息类型的，因为将每条消息作为其单独的类型使得很难拥有任何类型的通用消息处理程序。

有什么原因导致您不只拥有单一的消息数据类型吗？比如

data NetworkMsg 
    = NetworkMsg1 {fieldA :: Int} 
    | NetworkMsg2 {fieldB :: Int, fieldC :: Float} 

现在，虽然实例的构建方式几乎相同，但您可以获得更好的类型推断，因为结果类型始终是已知的。

instance Read a => MessageParser (a -> NetworkMsg) where 
    parseMsg con [a] = con <$> readMaybe a 
 
instance (Read a, Read b) => MessageParser (a -> b -> NetworkMsg) where 
    parseMsg con [a, b] = con <$> readMaybe a <*> readMaybe b 
 
instance (Read a, Read b, Read c) => MessageParser (a -> b -> c -> NetworkMsg) where 
    parseMsg con [a, b, c] = con <$> readMaybe a <*> readMaybe b <*> readMaybe c 
 
parseMessage :: String -> [String] -> Maybe NetworkMsg 
parseMessage tag fields = case tag of 
    "NetworkMsg1" -> parseMsg NetworkMsg1 fields 
    "NetworkMsg2" -> parseMsg NetworkMsg2 fields 
    _ -> Nothing 

我也不确定为什么要专门进行类型泛型编程而不实际使用任何用于泛型的工具。 GHC.Generics、SYB 或 Template Haskell 通常是此类问题的最佳解决方案。